;ᥬ஢ 㦭  䠩 "PC1"

஢ઠ ⨭ ᪠!
compar2	LD A,9
	LD (comp2+2),A
compare	CALL panel
	LD (comp6+1),A
	LD A,(LEFT_D+1)
	JR Z,comp1
	LD A,(RIGHT_D+1)
comp1	SUB 65
	LD (23833),A
	LD C,1
	CALL DOS2
	LD HL,LINE
comp2	LD BC,#0105
	LD DE,#0008
	LD A,B
	CP 1
	JR Z,comp21
	LD HL,BUFD+2304
	LD E,D
comp21	CALL DOS2
comp6	LD A,0
	AND A
	LD DE,BUFD+2304
	LD BC,2304
	LD HL,CAT_L
	JR Z,comp3
	LD HL,CAT_R
comp3	PUSH HL
	LD HL,comp2+2
	LD A,1
	CP (HL)
	LD (HL),A
	POP HL
	JR NZ,comp4
	LD DE,LINE
	ADD HL,BC
	LD BC,256
	AND A
	SBC HL,BC
comp4	LD A,(DE)
	CPI
	JR NZ,comp5
	INC DE
	JP PE,comp4
	RET
comp5	POP HL
	LD A,21
	LD (23823),A
	JP D_ERROR

QFILES	CALL panel
	LD B,A
	LD A,(QFILESL)
	JR Z,qfiles
	LD A,(QFILESR)
qfiles	AND A
	RET

cl_WIN	CALL panel
	JR Z,cl_WIN2
	LD A,32
cl_WIN2	LD H,A
	LD L,22
	LD DE,#011B
	LD A,7
	JP CL_WIN

ARRcurS	LD HL,(OLD_CRD)
	JP ARRcurs

;HL=HL*A
mul_hla	AND A
	JR Z,m1h
	EX DE,HL
	LD HL,0
m2h	SRL A
	JP NC,m3h
	ADD HL,DE
m3h	SLA E
	RL D
	AND A
	JP NZ,m2h
	RET
m1h	LD H,A
	LD L,A
	RET

	LD HL,(CRDS+1)
, , , ࠢ
udlr	LD E,A
	LD A,(FIRE_Q)
	DEC A
	JR Z,udlr2
	LD (FIRE_Q),A
	CP 29
	JP NZ,ARROW
udlr2	EXX
	CALL QFILES
	JP Z,ARROW
	CALL ARRcurS
	EXX
	LD A,E
	BIT 3,A
	JP NZ,Up
	BIT 2,A
	JP NZ,Down
	BIT 1,A
	JP NZ,Left
	BIT 6,A
	JP NZ,Last_fl
	BIT 5,A
	JP NZ,First

Right	EXX
	LD HL,(FILEadr)
	LD DE,216
	ADD HL,DE
	EXX
	INC HL
	LD A,(HL)
	LD B,A
	LD C,15
	AND 31
	ADD A,C
	CP 18
	JR C,right
	EXX
	LD B,H
	LD C,L
	ADD HL,DE
	LD DE,(END)
	AND A
	SBC HL,DE
	JR NC,LAST_FL
	LD (FILEadr),BC
	LD HL,(ADDER1+1)
	LD DE,216
	ADD HL,DE
	LD (ADDER1+1),HL
	LD HL,ADDER2+1
	LD A,(HL)
	ADD A,18
	LD (HL),A
	JP CAT_PRT
right	EXX
	LD B,H
	LD C,L
	LD DE,(END)
	AND A
	SBC HL,DE
	JR Z,right2
	JR NC,LAST_FL
right2	LD H,B
	LD L,C
	LD (FILEadr),HL
	EXX
	LD A,B
	ADD A,C
	LD (HL),A
	DEC HL
	CALL CURSOR
	JP ARROW2

Last_fl	INC HL
	EXX
	LD DE,(END)

 ⠥  ᫥ 䠩
LAST_FL	LD HL,(FILEadr)
	AND A
	SBC HL,DE
	JP Z,ARROW2 ;᫥ 䠩!
	EX DE,HL
	LD (FILEadr),HL
	AND A
	LD BC,420
	SBC HL,BC
	LD BC,(BEGIN)
	AND A
	SBC HL,BC
	JR C,last_f1
	LD (ADDER1+1),HL
last_f1	LD A,(PR_CATc+1)
	LD B,A
	CALL panel
	LD HL,QFILESL
	JR Z,last_f2
	LD HL,QFILESR
last_f2	LD A,(HL)
	SUB B
	LD (ADDER2+1),A
last_f3	LD A,B
	EXX
	LD C,19
	CP C
	JR C,last_f4
	INC A
	SUB C
	CP C
	JR C,last_f5
	DEC A
last_f5	LD B,A
	LD A,(HL)
	AND 32
	OR 17
	LD (HL),A
	LD A,B
last_f4	DEC HL
	LD (HL),A
	LD HL,(old_crd+1)
	CALL cursor3
	JP cat_prt

Left	EXX
	LD HL,(FILEadr)
	LD DE,216
	AND A
	SBC HL,DE
	LD B,H
	LD C,L
	EXX
	INC HL
	LD A,(HL)
	LD B,A
	LD C,15
	AND 31
	CP 17
	JR NC,left
	EXX
	LD HL,(BEGIN)
	LD DE,(ADDER1+1)
	ADD HL,DE
	AND A
	LD DE,216
	SBC HL,DE
	LD DE,(BEGIN)
	AND A
	SBC HL,DE
	JR C,FIRST
	LD (FILEadr),BC
	LD HL,(ADDER1+1)
	LD DE,216
	AND A
	SBC HL,DE
	LD (ADDER1+1),HL
	LD HL,ADDER2+1
	LD A,(HL)
	SUB 18
	LD (HL),A
	JP CAT_PRT

left	EXX
	LD HL,(BEGIN)
	LD DE,(ADDER1+1)
	ADD HL,DE
	LD DE,216
	LD DE,(BEGIN)
	AND A
	SBC HL,DE
	JR C,FIRST
	LD (FILEadr),BC
	EXX
	LD A,B
	SUB C
	LD (HL),A
	DEC HL
	CALL CURSOR
	JP ARROW2

First	INC HL
	LD A,(HL)
	LD B,A
	EXX
 ⠥  	䠩
FIRST	LD HL,0
	LD (ADDER1+1),HL
	LD A,H
	LD (ADDER2+1),A
	LD DE,(BEGIN)
	LD HL,(FILEadr)
	AND A
	SBC HL,DE
	JP Z,ARROW2
	LD (FILEadr),DE
	EXX
	LD A,B
	AND 32
	ADD A,2
	LD (HL),A
	DEC HL
	LD (HL),1
	LD HL,(old_crd+1)
	CALL cursor3
	JP cat_prt

Up	EXX
	LD HL,(FILEadr)
	LD BC,12
	AND A
	SBC HL,BC
	LD D,H
	LD E,L
	LD BC,(BEGIN)
	AND A
	SBC HL,BC
	JP C,ARROW2
	EX DE,HL
	LD (FILEadr),HL
	EXX
	LD A,(HL)
	DEC A
	JR NZ,up
	INC HL
	LD A,(HL)
	LD B,A
	LD C,15
	AND 31
	SUB C
	JR NC,up2
	LD HL,(ADDER1+1)
	LD DE,12
	AND A
	SBC HL,DE
	LD (ADDER1+1),HL
	LD HL,ADDER2+1
	DEC (HL)
	JP CAT_PRT
up2	LD A,B
	SUB C
	LD (HL),A
	DEC HL
	LD A,18
up	LD (HL),A
	CALL CURSOR
	JP ARROW2

Down	EXX
	LD HL,(FILEadr)
	LD BC,(END)
	LD D,H
	LD E,L
	AND A
	SBC HL,BC
	JP NC,ARROW2
	EX DE,HL
	LD BC,12
	ADD HL,BC
	LD (FILEadr),HL
	EXX
	LD A,(HL)
	INC A
	CP 19
	JR C,down
	INC HL
	LD A,(HL)
	LD B,A
	LD C,15
	AND 31
	ADD A,C
	CP 18
	JR C,down2
	LD HL,(ADDER1+1)
	LD DE,12
	ADD HL,DE
	LD (ADDER1+1),HL
	LD HL,ADDER2+1
	INC (HL)
CAT_PRT	LD HL,(CRDS+1)
	LD E,(HL)
	INC HL
	LD D,(HL)
	EX DE,HL
	CALL cursor2
cat_prt	CALL CAT
	JP Arrow2

down2	LD A,B
	ADD A,C
	LD (HL),A
	DEC HL
	LD A,1
down	LD (HL),A
	CALL CURSOR
	JP ARROW2

  ࠡ饣  
;HL= न 
CURSOR	LD E,(HL)
	INC HL
	LD D,(HL)
CURSOR2	EX DE,HL
	LD B,H
	LD C,L
old_crd	LD DE,0
	AND A
	SBC HL,DE
	EX DE,HL
	RET Z
	CALL Mcursor
	LD H,B
	LD L,C
cursor2	LD (old_crd+1),HL
cursor3	LD A,L
	LD (MRK_MS0+1),A
	CALL Mcursor
c3	CALL panel
	LD HL,FILE_L
	JR Z,cursor5
	LD HL,FILE_R
cursor5	LD (curss+1),HL
	LD HL,(FILEadr)
curss	LD (#2222),HL
cursor4	LD D,3
	JR Z,curs4
	LD D,35
curs4	LD E,#14
	CALL PRINT
	INC HL
	LD A,(HL)    ;A= 䠩
	AND 127
	LD (FILEnum),A
	LD HL,16
MUL_HLA	AND A		;HL=HL*A
	JP Z,M1H
	EX DE,HL
	LD HL,0
M2H	SRL A
	JP NC,M3H
	ADD HL,DE
M3H	SLA E
	RL D
	AND A
	JP NZ,M2H
	JP M4H
M1H	LD H,A
	LD L,A

M4H	EX DE,HL
	CALL panel
	LD HL,CAT_L
	JR Z,curs6
	LD HL,CAT_R
curs6	LD BC,9
	ADD HL,BC
	ADD HL,DE   ;HL=  䠩  ⠫ ᪠!

	LD E,(HL)
	INC HL
	LD D,(HL)
	INC HL
	EX DE,HL
HL_NUM	CALL DD_NUM
	LD HL,LINE
	LD A,D
	LD D,48
	CP D
	JR NZ,num5
	LD A,E
	CP D
	JR NZ,num4
	LD A,B
	CP D
	JR NZ,num3
	LD A,C
	CP D
	JR NZ,num2
	JR num1
num5	LD (HL),A
	INC HL
num4	LD (HL),E
	INC HL
num3	LD (HL),B
	INC HL
num2	LD (HL),C
	INC HL
num1	EX AF,AF'
	LD (HL),A
	INC HL
HL_MOD	NOP
	LD (HL),","
	INC HL
	EXX
	EX DE,HL
	LD E,(HL)
	INC HL
	LD D,(HL)
	INC HL
	EX DE,HL
	CALL DD_NUM
	LD A,D
	LD D,48
	CP D
	JR NZ,Num5
	LD A,E
	CP D
	JR NZ,Num4
	LD A,B
	CP D
	JR NZ,Num3
	LD A,C
	CP D
	JR NZ,Num2
	JP Num1
Num5	LD (HL),A
	INC HL
Num4	LD (HL),E
	INC HL
Num3	LD (HL),B
	INC HL
Num2	LD (HL),C
	INC HL
Num1	EX AF,AF'
	LD (HL),A
	INC HL
	LD (HL),"<"
	INC HL
	EXX
	EX DE,HL
	LD A,(HL)  ;A= 䠩  ᥪ
	LD (FILEsiz),A
	EXX
	LD B,D	;D=48
	LD C,D
	LD E,10
	CP 200
	JR C,SM_200
	LD B,"2"
	SUB 200
SM_200	CP 100
	JR C,SM_100
	INC B
	SUB 100
SM_100	CP E
	JR C,SM_10
	INC C
	SUB E
	JP SM_100
SM_10	ADD A,D
	EX AF,AF'
	LD A,B
	CP D
	JR NZ,NUm3
	LD A,C
	CP D
	JR NZ,NUm2
	JP NUm1
NUm3	LD (HL),B     ;⭨
	INC HL
NUm2	LD (HL),C     ;⪨
	INC HL
NUm1	EX AF,AF'     ;
	LD (HL),A
	INC HL
	LD (HL),">"
	INC HL
	LD (HL),0

	CALL panel
	LD D,14
	LD A,20
	JR Z,curs5
	LD D,46
	LD A,52
curs5	EXX
	LD L,20
	LD H,A
	LD DE,#010A
	LD A,15
	CALL CL_WIN
	EXX
	LD E,#14
	LD HL,LINE
	JP PRINT

mouse	LD A,(MOUSE)
	AND A
	RET Z

	LD BC,#FBDF
m1	LD D,63
	LD HL,COORDS+1	 ; lef/right
	IN A,(C)
TM_A1	LD E,0
	LD (TM_A1+1),A
	SUB E
	JR Z,NXT_1
	JP P,RIGHT
	CALL SPEED0
	LD B,A
	LD A,(HL)
	SUB B
	JR NC,pl2
	XOR A
	JR pl2
RIGHT	CALL SPEED1
	ADD A,(HL)
	JR C,Rmax
	CP D
	JR C,pl2
Rmax	LD A,D
pl2	LD (HL),A
	LD DE,#0218
	LD (ARROW),DE

NXT_1	DEC HL
	LD B,#FF
m2	LD D,23
	IN A,(C)
TM_A2	LD E,0
	LD (TM_A2+1),A
	SUB E
	JR Z,r_key
	NEG
	JP P,DOWN
	CALL SPEED0
	LD B,A
	LD A,(HL)
	SUB B
	JR NC,pl22
	XOR A
	JR pl22
DOWN	CALL SPEED1
	ADD A,(HL)
	JR C,Dmax
	CP D
	JR C,pl22
Dmax	LD A,D
pl22	LD (HL),A
	LD DE,#0218
	LD (ARROW),DE

r_key	LD B,#FA
	IN A,(C)
	LD H,A
	BIT 1,H	       ; RIGHT KEY
	LD A,128
	RET Z
	BIT 0,H
	LD A,16
	RET Z
	XOR A
	RET

ࠬ . 	"PC"
WINDOW	LD (LENcurs),BC
	EXX
	PUSH HL
	PUSH HL
	LD (AT_BOX),HL
	LD (WDH_BOX),DE
	LD (ATcurs),BC
	CALL CL_WIN

	LD A,(WDH_BOX)
	LD E,A
	LD HL,LINE
	LD A,"+"    ; 201
	LD (HL),A
	LD A,"-"    ; 205
Fill_1	INC HL
	DEC E
	LD (HL),A
	JR NZ,Fill_1

	LD (HL),E
	DEC HL
	LD (HL),"+" ; 187

	POP DE
	LD HL,LINE
	CALL PRINT

	DEC HL
	LD (HL),"+" ; 188

	LD HL,LINE
	LD (HL),"+" ; 200
	POP DE
	LD A,(WDH_BOX+1)
	ADD A,E
	LD E,A
	DEC E
	CALL PRINT

	LD HL,(WDH_BOX)
	LD DE,(AT_BOX)
	INC E
	DEC L
	LD A,L
	LD (What+1),A
	DEC H
	RET Z
	DEC H
	RET Z
PrVER	PUSH HL
	PUSH DE
	PUSH DE
	LD HL,VER
	CALL PRINT
	POP DE
	LD A,D
What	ADD A,0
	LD D,A
	DEC HL
	CALL PRINT
	POP DE
	INC E
	POP HL
	DEC H
	JP NZ,PrVER
	RET

;Clear window &	SET attr.
CL_WIN	EX AF,AF'
	LD A,E
	ADD A,H
	SRL H
	SRL A
	JR NC,cl_win
	INC E
cl_win	SRL E
	JR NC,cl_win1
	INC E
cl_win1	LD A,E
	LD (Cl_len+1),A
	LD (Atr_len+1),A
	PUSH HL
	CALL SCR_ADR
	LD A,D
	ADD A,A
	ADD A,A
	ADD A,A
	LD B,A
	LD C,0

LOOP_CS	PUSH HL
Cl_len	LD A,0
LOOP_CL	LD (HL),C
	INC HL
	DEC A
	JR NZ,LOOP_CL
	POP HL

	INC	H   ;  ப 
	LD	A,H ; LINEHL
	AND	7
	JR	NZ,lpcs
	LD	A,L
	ADD	A,32
	LD	L,A
	JR	C,lpcs
	LD	A,H
	SUB	8
	LD	H,A

lpcs	DJNZ LOOP_CS

	POP HL		;SET attr.

	LD A,L
	AND #07		;INPUT:	HL-"AT"
	RRCA		;OUTPUT: HL-ADDRES ATTRIB.
	RRCA
	RRCA
	ADD A,H
	LD H,L
	LD L,A
	LD A,H
	AND #18
	RRCA
	RRCA
	RRCA
	OR #58
	LD H,A

	LD A,32
Atr_len	LD E,0
	SUB E
	LD C,A
	EX AF,AF'
	LD B,E
LOOP_AT	LD (HL),A
	INC HL
	DJNZ LOOP_AT
	ADD HL,BC
	DEC D
	JR NZ,LOOP_AT-1
	RET

⠭ ਡ⮢    . HL
⮩	D, ਭ E, ਡ⮬	A.
SET_ATR	LD B,A
atr_adr	LD A,L
	AND #07
	RRCA
	RRCA
	RRCA
	ADD A,H
	LD H,L
	LD L,A
	LD A,H
	AND #18
	RRCA
	RRCA
	RRCA
	OR #58
	LD H,A
	LD A,32
	SUB E
	LD C,A
	LD A,B
	LD B,E
loop_at	LD (HL),A
	INC HL
	DJNZ loop_at
	ADD HL,BC
	DEC D
	JR NZ,loop_at-1
	RET

 誨
ARRcurs	LD A,(MOUSE)
	AND A
	RET Z
	LD D,H
scr_adr	LD A,L
	AND 7
	RRCA
	RRCA
	RRCA
	SRL H
	ADD A,H
	LD H,L
	LD L,A
	LD A,H
	AND #18
	OR #40
	LD H,A
	LD A,D
	RRCA
	LD D,240
	JR NC,NCARRY
	LD D,15
NCARRY	LD E,8
	LD A,(HL)
	XOR D
	LD (HL),A
	INC H
	DEC E
	JR NZ,NCARRY+2
	RET

८ࠧ ᫠ HL	 ᨬ 
DD_NUM	LD BC,10000
	CALL PR_SUB
	LD D,A
	EXX
DD_NUM2	LD BC,1000
	CALL PR_SUB
	LD E,A
	EXX
	LD BC,100
	CALL PR_SUB
	LD B,A
	EXX
	LD BC,10
	CALL PR_SUB
	LD C,A
	EXX
	LD A,L
	ADD A,48
	EX AF,AF'
	EXX
	RET
PR_SUB	XOR A
PR_S1	INC A
	SBC HL,BC
	JP NC,PR_S1
	DEC A
	ADD HL,BC
	EXX
	ADD A,48
	RET

SCR_ADR	LD A,L	;"AT_COORD" INTO SCREEN	ADDRES
	AND 7
	RRCA
	RRCA
	RRCA
	ADD A,H
	LD H,L
	LD L,A
	LD A,H
	AND #18
	OR #40
	LD H,A
	RET

SCANER	LD A,#BF	;ENTER
	IN A,(#FE)
	AND 1
	LD A,16
	RET Z

	LD A,#FE	;CS
	IN A,(#FE)
	AND 1
	LD A,0
	RET NZ

	LD C,1
	LD A,#EF	;CURSOR
	IN A,(#FE)
	RRCA
	RRCA
	RRCA
	PUSH AF
	RRCA
	RL C
	RRCA
	RL C
	LD A,#F7      ;"1"-"5"
	IN A,(#FE)
	LD B,192
	BIT 0,A
	JR Z,ex_c
	LD B,A
	BIT 2,A
	JR Z,up_dn
	BIT 3,A
	JR NZ,nxt_c
up_dn	POP AF
	LD A,B
	CPL
	AND 12
	RLA
	RLA
	RLA
	RET
	LD B,128
ex_c	POP AF
	LD A,B	     ;7- -escape
	RET
nxt_c	LD A,#7F
	IN A,(#FE)
	AND 1
	JR Z,ex_c-2
	LD A,B
	AND 16
	ADD A,255
	RL C
	POP AF
	RL C
	LD A,C
	CPL
	AND 31
	RET

;	⥪:	HL- ⥪,
;D-X, E-Y (  4*8)
;0<=X<=64 (0...64)
;0<=Y<=23 (0...23)
PRINT	PUSH DE
	LD B,D
	LD A,E	;AT-.  SCREEN ADDR.
	AND 7
	RRCA
	RRCA
	RRCA
	SRL D
	ADD A,D
	LD D,E
	LD E,A
	LD A,D
	AND #18
	OR #40
	LD D,A
	LD A,B
PRNT	LD (COUNT+1),A
	CP 64  ;諨  । ࠭?
	JP C,PRNT2
	POP DE
PRNT1	LD A,(HL)
	AND A  ; ⥪?
	RET Z
	INC HL
	CP #0D
	RET Z
	JP PRNT1

PRNT2	LD A,(HL)
	AND A
	JP NZ,PRNT_1
pr_exit	POP DE
	RET
PRNT_2	LD A,(COUNT+1)
	RRCA
	JR NC,NXt2
	INC E
NXt2	RLCA
	INC A
	INC HL
	JP PRNT
PRNT_1	CP 255
	JP Z,PRNT_2
	CP 13
	JP NZ,PRNT_4
	POP DE
	INC HL
PrntMod	NOP
	INC E
	JP PRINT
PRNT_4	CP 32
	JP NC,PRNM
	LD A,"?"
PRNM	INC HL
	PUSH DE
	EXX
	POP DE
	LD L,A
	LD H,0
	ADD HL,HL
	ADD HL,HL
	ADD HL,HL
	LD BC,FONT-256
	ADD HL,BC

	LD BC,#F00F
COUNT	LD A,0
	RRCA
	JR C,NotRol
	LD BC,#0FF0

NotRol	EX AF,AF'
	EX DE,HL
	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A
	INC H
	INC DE

	LD A,(HL)
	AND B
	LD (HL),A
	LD A,(DE)
	AND C
	OR (HL)
	LD (HL),A

	EX AF,AF'
	EXX
	JR NC,Nxt2
	INC E
Nxt2	RLCA
	INC A
	JP PRNT

DelFile	LD HL,(FILEadr)
	LD A,(HL)
	DEC A
	RET

ન஢ 䠩!
MARK	CALL QFILES
	JP Z,ARROW2
	CALL DelFile
	EXX
	JP Z,MRK_MOD
	EXX
	LD A,B
	AND A
	LD BC,MARKEDL
	LD D,B
	LD E,C
	LD HL,(MRKadrL)
	JR Z,mark1
	LD BC,MARKEDR
	LD D,B
	LD E,C
	LD HL,(MRKadrR)
mark1	PUSH HL
	SBC HL,BC
	JR Z,firstM
	LD B,H
	LD C,L
	EX DE,HL       ;HL=  ⬥. -
	LD A,(FILEnum) ;BC=- ⬥. -
	CPIR
	POP DE
	JR NZ,firstMN
	CALL panel
	EX DE,HL
	LD HL,(MRKadrL)
	JR Z,mark2
	LD HL,(MRKadrR)
mark2	SBC HL,DE
	LD B,H
	LD C,L
	EX DE,HL
	LD D,H
	LD E,L
	DEC DE
	JR Z,mark3
	LDIR

mark3	EX DE,HL
	AND A
	LD DE,MRKadrL
	JR Z,mark5
	LD DE,MRKadrR
mark5	EX DE,HL
	LD (HL),E
	INC HL
	LD (HL),D

	LD BC,(FILEsiz)
	LD DE,MARK_L
	LD HL,(MARK_L)
	JR Z,mark4
	LD HL,(MARK_R)
	LD DE,MARK_R
mark4	SBC HL,BC
	EX DE,HL
	LD (HL),E
	INC HL
	LD (HL),D
	JR firstM3

  ⬥祭 䠩
firstM	POP DE
	LD A,(FILEnum)
firstMN	LD (DE),A
	INC DE
	CALL panel
	LD HL,MRKadrL
	JR Z,firstM1
	LD HL,MRKadrR
firstM1	LD (HL),E
	INC HL
	LD (HL),D
	LD BC,(FILEsiz)
	LD HL,(MARK_L)
	LD DE,MARK_L
	JR Z,firstM2
	LD HL,(MARK_R)
	LD DE,MARK_R
firstM2	ADD HL,BC
	EX DE,HL
	LD (HL),E
	INC HL
	LD (HL),D
firstM3	NOP
	EXX
	PUSH HL
	PUSH HL
	EXX
	EX DE,HL
M_print	CALL DD_NUM2
	LD HL,LINE
	LD D,48
	LD A,E
	CP D
	JR NZ,nUm4
	LD A,B
	CP D
	JR NZ,nUm3
	LD A,C
	CP D
	JR NZ,nUm2
	EX AF,AF'
	CP D
	JR NZ,nUm1+1
	CALL cl_WIN
	JP NotMrk0

nUm5	LD (HL),A
	INC HL
nUm4	LD (HL),E
	INC HL
nUm3	LD (HL),B
	INC HL
nUm2	LD (HL),C
	INC HL
nUm1	EX AF,AF'
	LD (HL),A
	INC HL
	EX DE,HL
	LD HL,MarkPar
	LD BC,5
	LDIR
	INC HL
	LD C,4
	LDIR

	CALL panel
	LD BC,MARKEDL
	LD HL,(MRKadrL)
	JR Z,Markl
	LD BC,MARKEDR
	LD HL,(MRKadrR)
Markl	SBC HL,BC
	LD A,L	 ;A=- ⬥. -
	EX DE,HL

D_NUM	LD B,48
	LD C,B
sM_200	CP 100
	JR C,sM_100
	INC B
	SUB 100
sM_100	CP 10
	JR C,sM_10
	INC C
	SUB 10
	JP sM_100
sM_10	ADD A,48

	EX AF,AF'
	LD A,B
	CP 48
	JR NZ,Hund
	LD A,C
	CP 48
	JR NZ,Ten
	JR One
Hund	LD (HL),B
	INC HL
Ten	LD (HL),C
	INC HL
One	EX AF,AF'
	LD (HL),A
	INC HL
	EX DE,HL
	LD HL,MarkPar+10
	LD BC,11
	LDIR
	EX DE,HL
	LD (HL),C

	CALL panel
	JR Z,NMK
	LD A,32
NMK	LD D,A
	EXX
	LD L,22
	ADD A,L
	LD H,A
	LD DE,#0105
	LD A,7
	CALL CL_WIN

	EXX
	LD E,22
	LD HL,LINE
	CALL PRINT

NotMrk0	NOP
	LD HL,(FILEadr)
	LD DE,11
	ADD HL,DE
	LD A,(HL)
	XOR 128
	LD (HL),A
	POP HL
	LD E,(HL)
	INC HL
	LD D,(HL)
	EX DE,HL
	AND 128
	LD A,15
	JR Z,NotMrk;  ⬥祭!
	LD A,8+3
NotMrk	INC H
	SRL H
	LD DE,#0106
	JR C,nm2
	DEC H
	INC E
nm2	CALL SET_ATR
	POP HL
MRK_MOD	NOP
	JP Down

. 䠩
DELETE	CALL QFILES
	JP Z,ARROW
	CALL del2
	JR NZ,Dl
	CALL DelFile
	JR Z,DELETE+3
Dl	CALL ARRcurS
	CALL panel
	PUSH AF
	LD HL,#0605
	LD DE,#0314
	LD BC,#0806
	JR Z,DEL0
	LD H,6+32
	LD B,8+32
DEL0	EXX
	LD BC,#0208
	LD A,24+7
	CALL WINDOW
	POP AF
	LD DE,#0905
	JR Z,DeL0
	LD D,9+32
DeL0	LD HL,del1
	CALL PRINT
	JP CONTROl

del2	CALL panel
	LD DE,MARKEDL
	LD HL,(MRKadrL)
	JR Z,DEL1
	LD DE,MARKEDR
	LD HL,(MRKadrR)
DEL1	SBC HL,DE
	RET

DEL_M	CALL compar2
⬥祭?
	CALL del2
	JR NZ,DEL1_1
	LD B,A
	LD A,(FILEnum)
	LD (DE),A
	LD L,1
	LD A,B
DEL1_1	AND A
	LD A,L
	EXX
	LD B,A	;B=- ⬥. -
	LD HL,CAT_L
	JR Z,Delf
	LD HL,CAT_R
Delf	LD (Delf1+1),HL
	LD (Delf4+1),HL
	LD HL,CAT_L+2048+228
	JR Z,DEL2
	LD HL,CAT_R+2048+228
DEL2	LD (Delf6+1),HL
	LD A,(HL)
	DEC A
	EXX
	LD B,L
	LD H,D
	LD L,E
FND_N	LD C,(HL)
	CP C
	JR Z,INC_MEM
	INC HL
	DJNZ FND_N

 	࠭ - 㦭
 	ᨬ	  1 
㢥 - 㤠 -!
	EXX
	LD A,B	;A=- . 䠩
Delf6	LD HL,0
	LD DE,16
	ADD HL,DE ;HL= - 㤠 䠩  ᪥
	EXX
	LD B,D
	LD C,E
Delf0	EX AF,AF'
	LD A,(BC)
	LD HL,16
	CALL mul_hla
Delf1	LD DE,0
	ADD HL,DE
	LD A,(HL)
	CP 2
	JR NC,Delf2
	EXX
	DEC (HL)
	EXX
	JP Delf3
Delf2	LD (HL),1
Delf3	INC BC
	EX AF,AF'
	DEC A
	JP NZ,Delf0
	EXX
	LD A,B
	ADD A,(HL) ;A=쪮 ⠫ 㤠. -
	LD (HL),A
	LD HL,(Delf1+1)
Delete	LD DE,0
	LD BC,#0906
	CALL DOS
	CALL Move
	JP NZ,Restart
	CALL CAT_CUR
	CALL SET_pan
	JP Arrow2

 ᫥ 䠩,  㦭
㢥. - ᥪ.  ᪥
INC_MEM	EXX
	EX AF,AF'
	LD A,B
	EX AF,AF'
	DEC (HL)  ;. - 䠩
	PUSH HL
	PUSH HL
	LD HL,16
	CALL mul_hla
Delf4	LD DE,0
	ADD HL,DE
	LD (HL),0 ;ਧ 㤠
	LD DE,13
	ADD HL,DE

	LD C,(HL)
	LD B,0
	POP DE
	PUSH HL
	EX DE,HL
	INC HL
	LD E,(HL)
	INC HL
	LD D,(HL)
	DEC HL
	EX DE,HL
	ADD HL,BC
	EX DE,HL
	LD (HL),E ;- ᢮.	ᥪ஢
	INC HL
	LD (HL),D
	LD DE,5
	AND A
	SBC HL,DE
	EX DE,HL
	POP HL
	INC HL
	LD C,(HL)
	INC HL
	LD B,(HL)
	EX DE,HL
	LD (HL),C ; ᢮.	ᥪ., 
	INC HL
	LD (HL),B

	EX DE,HL
	LD DE,31
	AND A
	SBC HL,DE
	LD A,(HL)
	POP HL
	EX AF,AF'
	LD B,A
	EXX
	LD H,D
	LD L,E
	LD B,A
	DEC C
	EX AF,AF'
	CP 1
	LD A,C
	JP NZ,FND_N
	EXX
	LD E,16
	ADD HL,DE
	DEC (HL)
	LD HL,(Delf6+1)
	EXX
	JP INC_MEM

READ	CALL panel
	LD A,(LEFT_D+1)
	JR Z,RD1
	LD A,(RIGHT_D+1)
RD1	SUB 65
READ2	LD (23833),A
	LD C,1
	CALL DOS2
	LD C,#18
	CALL DOS2
	CALL panel
	LD HL,CAT_L
	JR Z,LEFT1
	LD HL,CAT_R
LEFT1	LD BC,#0905
	LD DE,0
	CALL DOS2

	CALL panel
	LD DE,LEFT_D+1
	LD HL,CAT_L+2048+245
	JR Z,LEFT3
	LD DE,RIGHT_D+1
	LD HL,CAT_R+2048+245
LEFT3	LD A,(23833)
	ADD A,65
	LD (DE),A
	INC DE
	INC DE
	LD BC,8
	LDIR

CAT_CUR	CALL panel
	LD HL,COORD_L
	LD DE,#0201
	JR Z,LEFT1_1
	LD HL,COORD_R
	LD D,#22
LEFT1_1	LD (HL),E
	INC HL
	LD (HL),D

	LD HL,FILE_L
	LD DE,TXT_L
	LD BC,ADD1_L
	JR Z,LEFT3_4
	LD HL,FILE_R
	LD DE,TXT_R
	LD BC,ADD1_R
LEFT3_4	LD (HL),E
	INC HL
	LD (HL),D

	EX AF,AF'
	LD D,6
	XOR A
LEFT3_6	LD (BC),A
	INC BC
	DEC D
	JR NZ,LEFT3_6

	LD (RESTcat+1),A
	LD H,A
	LD L,A
	LD (ADDER1+1),HL
	LD (ADDER2+1),A

	EX AF,AF'
	LD HL,MRKadrL
	LD DE,MARKEDL
	JR Z,LEFT3_7
	LD HL,MRKadrR
	LD DE,MARKEDR
LEFT3_7	LD (HL),E
	INC HL
	LD (HL),D

஢ 䠩  ᪥
MASK	LD BC,8
	CALL panel
	LD HL,MASK_L
	JR Z,LEFT3_0
	LD HL,MASK_R
LEFT3_0	LD (nxt_fl+1),HL
	LD D,H
	LD E,L
	INC HL
	EX AF,AF'
	XOR A
	LD (Mode_5+1),A
	LD BC,#2EFF
LEFT3_2	LD A,(HL)
	CP B
	JR Z,LEFT3_1
	INC HL
	INC C
	JP LEFT3_2
LEFT3_1	LD A,C
	LD (LENmask+1),A
	LD (LENmsk+1),A
	LD H,D
	LD L,E
	EXX
	EX AF,AF'

	LD BC,2048+220
	LD HL,CAT_L+2048+228
	LD DE,TXT_L
	JR Z,LEFT3_3
	LD HL,CAT_R+2048+228
	LD DE,TXT_R
LEFT3_3	LD (Mode_2+1),DE
	LD A,(HL)     ;A=-	䠩
	AND A
	JR Z,FILTRe   ; 䨫樨
	LD (Mode_3+1),A
	SBC HL,BC     ;HL=. 䠩
	LD BC,8
COMPARE	EX AF,AF'
	LD A,(HL)
	EXX	      ;HL=᪠	
	LD C,A
	LD A,(HL)
	CP "*"
	JP Z,EXE_COM
	CP C
	JP Z,EXE_COM
	EXX
NXT_FL	EX AF,AF'
	ADD HL,BC
	ADD HL,BC
	DEC A
	JP NZ,COMPARE
 䠩  ᪥ ᬮ७,
 ...
FILTRe	CALL panel
	LD HL,QFILESL
	JR Z,LEFT3_5
	LD HL,QFILESR
LEFT3_5	LD A,(Mode_5+1)
	LD (HL),A
	CALL cl_WIN

⠥ ࠡ 
WINS	CALL panel
	LD HL,#0000
	JR Z,LEFT4
	LD H,32
LEFT4	LD DE,#161F
	LD A,15
	EXX
	LD B,0
	CALL WINDOW

	CALL panel
	LD DE,#0113
	JR Z,LEFT5
	LD D,33
LEFT5	LD A,193
	LD (INFOlin+15),A
	LD HL,INFOlin+1
	CALL PRINT

	CALL panel
	LD A,15
	JR Z,LEFT6
	LD A,47
LEFT6	LD (rle+1),A
	LD E,1
	LD A,18
	LD HL,VER2
verline	PUSH AF
rle	LD D,15
	CALL PRINT
	INC E
	POP AF
	DEC A
	DEC HL
	JP NZ,verline

 ᪠
DISKNAM	CALL panel
	LD DE,#0900
	LD HL,LEFT_D
	JR Z,LEFT8
	LD HL,RIGHT_D
	LD D,41
LEFT8	CALL PRINT

	CALL panel
	LD HL,(FILE_L)
	JR Z,LFT8
	LD HL,(FILE_R)
LFT8	JP cursor4

७ ᮢ!
EXE_COM	INC HL
	EXX
	LD D,H
	LD E,L
   䠩
FND_END	DEC HL
	LD A,(HL)
	CP 32
	JR NZ,ENDname
	DEC C
	JP NZ,FND_END
ENDname	LD A,C
	LD (LENname+1),A ;A= 
	AND A
	INC HL
	SBC HL,BC     ;HL= 䠩
nxt_sgn	LD C,(HL)
	LD A,(DEL)    ;.㤠.䠩?
	AND A
	LD A,C
	EXX	      ;HL=᪠	
	JR Z,nxt_sg2
	CP 1
	JR Z,nxt_fl
nxt_sg2	LD A,(HL)
	CP "*"
	JR Z,COMP0
	EXX
	CP C
	EXX
	JR Z,COMP

 	襫  ᪥,
 	᫥騩!
nxt_fl	LD HL,MASK_L  ;	MASK_R
	EXX
	LD BC,8
	LD H,D
	LD L,E
LENmsk	LD A,0
	LD (LENmask+1),A
	JP NXT_FL

  ᨬ    ᪮
COMP0	INC HL
	LD A,(HL)
	CP "."
	JP Z,COPY
LENmask	LD C,0
COMP1	LD A,(HL)
	CP "*"
	JR Z,NXT_SYM
	INC HL
	DEC C
	JP NZ,COMP1

	DEC HL
	LD A,(LENname+1)
	EXX
	LD C,A
	DEC C
	ADD HL,BC

	LD A,(LENmask+1)
	LD B,A
find	LD A,(HL)
	EXX
	CP (HL)
	JP NZ,nxt_fl
	DEC HL
	EXX
	DEC HL
	DJNZ find
	JP COPY+1

NXT_SYM	LD A,(LENmask+1)
	SUB C
	LD C,A
	LD B,0
	AND A
	SBC HL,BC
	DEC HL

COMP	INC HL
	EXX
	INC HL
	LD A,(LENmask+1)
	DEC A
	LD (LENmask+1),A
LENname	LD A,0
	DEC A
	LD (LENname+1),A
	JP NZ,nxt_sgn
	EXX
	LD A,(HL)
	CP "."
	JP NZ,nxt_fl

  襫  ᪥,
㥬   !
COPY	EXX
	PUSH DE
	LD H,D
	LD L,E
	LD C,8
	AND A
	SBC HL,BC
Mode_2	LD DE,TXT_L
	LDIR
	LD A,32
	LD (DE),A
	INC DE
	LDI
	XOR A
	LD (DE),A
	EX AF,AF'
	LD C,A
	EX AF,AF'
Mode_3	LD A,0
	SUB C
	INC DE
	LD (DE),A  ; 䠩	 ⠫
	INC DE
	LD (Mode_2+1),DE
Mode_5	LD A,0	  ;稪 䠩 襤 䨫!
	INC A
	LD (Mode_5+1),A
	POP DE
	LD BC,8
	EXX
	JP nxt_fl

ન஢ 䠩  ᪥,  㦥
䨫஢
;A=4,  ⬥ 䠩
;A=8,  뢠 䠩
;A<>4 and A<>8,	 ஢ 䠩
MASK2	CP 4
	LD HL,#80F6	;OR 128
	JR Z,MASK2_1
	CP 8
	LD L,#EE	;XOR 128
	JR NZ,MASK2_1
	LD HL,#7FE6	;AND 127
MASK2_1	LD (MARKmod),HL
	LD HL,MASK_FL
	LD D,H
	LD E,L
	INC HL
	LD BC,#2EFF
mask2_0	LD A,(HL)
	CP B   ; "."
	JR Z,mask2_1
	INC HL
	INC C
	JP mask2_0
mask2_1	LD A,C
	LD (lenmask+1),A
	LD (lenmsk+1),A
	LD H,D
	LD L,E
	EXX
	CALL panel
	LD HL,QFILESL
	JR Z,mask2_2
	LD HL,QFILESR
mask2_2	LD A,(HL)     ;A=-	䠩
	LD BC,12
	LD HL,TXT_L+9
	JR Z,mask2_3
	LD HL,TXT_R+9
mask2_3	AND A
	RET Z	      ; ન஢
Compare	EX AF,AF'
	LD A,(HL)     ;HL=. 䠩
	EXX
	LD C,A
	LD A,(HL)     ;HL=᪠	
	CP "*"
	JR Z,exe_com
	CP C
	JR Z,exe_com
	EXX
Nxt_fl	EX AF,AF'
	ADD HL,BC
	DEC A
	JP NZ,Compare
 䠩 ᬮ७!
MARKend	RET

७ ᮢ!
exe_com	INC HL
	EXX
	LD D,H
	LD E,L
   䠩
	DEC HL
	LD C,8
FND_LEN	DEC HL
	LD A,(HL)
	CP 32
	JR NZ,endname
	DEC C
	JP NZ,FND_LEN
endname	LD A,C
	LD (lenname+1),A ;A= 
	AND A
	INC HL
	SBC HL,BC     ;HL= 䠩
Nxt_Sgn	LD C,(HL)
	LD A,C
	EXX	      ;HL=᪠	
	CP 1
	JR Z,nxt_fl2
	LD A,(HL)
	CP "*"
	JR Z,Comp0
	EXX
	CP C
	EXX
	JR Z,Comp

 	襫  ᪥,
 	᫥騩
nxt_fl2	LD HL,MASK_FL
	EXX
	LD H,D
	LD L,E
lenmsk	LD A,0
	LD (lenmask+1),A
	LD BC,12
	JP Nxt_fl

 1- ᨬ    ᪮
Comp0	INC HL
	LD A,(HL)
	CP "."
	JP Z,MARK_FL
lenmask	LD C,0
Comp1	LD A,(HL)
	CP "*"
	JR Z,Nxt_sym
	INC HL
	DEC C
	JP NZ,Comp1

	DEC HL
	LD A,(lenname+1)
	EXX
	LD C,A
	DEC C
	ADD HL,BC

	LD A,(lenmask+1)
	LD B,A
Find	LD A,(HL)
	EXX
	CP (HL)
	JP NZ,nxt_fl2
	DEC HL
	EXX
	DEC HL
	DJNZ Find
	JP MARK_FL+1

Nxt_sym	LD A,(lenmask+1)
	SUB C
	LD C,A
	LD B,0
	AND A
	SBC HL,BC
	DEC HL

Comp	INC HL
	EXX
	INC HL
	LD A,(lenmask+1)
	DEC A
	LD (lenmask+1),A
lenname	LD A,0
	DEC A
	LD (lenname+1),A
	JP NZ,Nxt_Sgn
	EXX
	LD A,(HL)
	CP "."
	JP NZ,nxt_fl2

  襫  ᪥,
㥬   !
MARK_FL	EXX
	LD H,D
	LD L,E
	INC HL
	INC HL
	LD A,(HL)
 ન஢: ⬥(+) 
뢠(-) 䠩
MARKmod	OR 128	   ;AND	127/XOR	128
	LD (HL),A
	EXX
	JP nxt_fl2

 ⥪饣 䠩   
SET_pan	CALL W_11

뤥 	᪠
SET_PAN	CALL panel
	LD HL,#0500
	JR Z,LEFT7
	LD H,21
LEFT7	LD DE,#0105
	LD A,15+64
	CALL SET_ATR

;	⠫ ᪠
;HL- ⠫
;BC-  ᮤন -	䠩
CAT	CALL panel ;  砫 ⥪	 
	LD HL,TXT_L   ; 
	LD BC,QFILESL
	JR Z,LEFT9
	LD HL,TXT_R  ;ࠢ 
	LD BC,QFILESR
LEFT9	EX AF,AF'
	LD (BEGIN),HL
	LD A,(BC)    ;A=- 䠩
	AND A
	RET Z
	LD B,A
	LD C,A
	LD DE,12
	SBC HL,DE
ADDER0	ADD HL,DE
	DJNZ ADDER0
	LD (END),HL
CAT_MOD	NOP

	LD HL,(BEGIN)
饭  뢮 ⠫
ADDER1	LD DE,0
	ADD HL,DE
	LD DE,#0301  ;.
	EX AF,AF'
	JR Z,LEFT10
	LD D,#23
LEFT10	XOR A
	LD (PR_CATc+1),A
	LD A,C	     ;A=- 䠩
ADDER2	SUB 0	     ;ᬥ饭 䠩
PR_CAT	LD (PR_CATa+1),A
	CALL PRINT
	INC HL
	PUSH DE
	LD A,(HL)
	EXX
	AND 128
	LD A,15
	JR Z,NotMark;  ⬥祭
	LD A,8+3
NotMark	POP HL
	SRL H
	LD DE,#0106
	JR C,NM2
	DEC H
	INC E
NM2	CALL SET_ATR
	EXX
PR_CATc	LD B,0
	INC HL
	INC E
	INC B
	LD A,B
	LD (PR_CATc+1),A
PR_CATa	LD A,0
	DEC A
	RET Z
	LD C,A
	LD A,B
	CP 18 ; 	1- ⮫
	LD A,C
	JR C,PR_CAT
	LD A,B
	CP 19
	JR NC,PR_CAT2
	LD A,D
	ADD A,15
	LD D,A
	LD E,1
	LD A,B
PR_CAT2	CP 36 ;  2- ⮫
	LD A,C
	JR C,PR_CAT
	RET


Mcursor	LD A,12	; .
curs_0	EX AF,AF'
	PUSH HL
	CALL scr_adr-1
	POP HL
	INC H
	EX AF,AF'
	DEC A
	JP NZ,curs_0
	RET

ન஢ 䠩  ᪥
Mark	LD (Mas_Mod+1),A
	LD HL,Sel
	CP 4
	JR Z,Mar1
	LD HL,Unsel
Mar1	LD (Mas2+1),HL
	JR Mask2
஢ 䠩  ᪥
Mask	LD HL,Msk
	LD (Mas2+1),HL
	XOR A
	LD (Mas_Mod+1),A
Mask2	CALL ARRcuRS
	CALL panel
	PUSH AF
	PUSH AF
	LD HL,#070F
	LD DE,#0312
	JR Z,Mas1
	LD H,7+32
Mas1	EXX
	LD A,40+64
	CALL WINDOW
	POP AF
	LD DE,#0B0F
	JR Z,Mas2
	LD D,11+32
Mas2	LD HL,Msk
	CALL PRINT
Mas_Mod	LD A,0
	AND A
	JR Z,Mas2_1
	POP AF
	LD HL,MASK_FL
	JR Mas3
Mas2_1	POP AF
	LD HL,MASK_L
	JR Z,Mas3
	LD HL,MASK_R
Mas3	LD DE,LINE
	PUSH HL
	PUSH DE
	PUSH AF
	LD A,(HL)
	EX AF,AF
	LD BC,#2009
	INC HL
Mas4	LD A,(HL)
	CP "."
	LDI
	JR NZ,Mas4
	EX AF,AF'
	LD (DE),A
	INC DE
	LD A,C
	AND A
	JR Z,Mas6
	LD A,B
	LD B,C
Mas7	LD (DE),A
	INC DE
	DJNZ Mas7
Mas6	POP AF
	POP HL
	LD DE,#0B10
	JR Z,Mas8
	LD D,11+32
Mas8	CALL INP_STR
	POP DE
	JR NZ,Mas_Esc
	PUSH DE
	INC DE
	LD HL,LINE
	LD A,(HL)
	CP "?"
	JR NZ,Mas8_1
	LD (HL),1
Mas8_1	LD BC,#2E09
Mas9	LD A,(HL)
	CP B
	LDI
	JR Z,Mas9_1
	LD A,C
	AND A
	JR NZ,Mas9
	JR Mas91
Mas9_1	LD A,(HL)
	POP HL
	LD (HL),A
	JR Mas90
Mas91	POP HL
Mas90	EX DE,HL
	LD BC,#2008
	DEC HL
Mas9_0	DEC HL
	LD A,(HL)
	CP B
	JR NZ,Mas9_11
	DEC C
	JR NZ,Mas9_0
	LD (HL),"*"
Mas9_11	INC HL
	LD (HL),"."
	LD A,(Mas_Mod+1)
	AND A
	JR NZ,Mark2
Mas_Yes	CALL CAT_CUR
	CALL SET_pan
	JR Mas10
Mas_Esc	CALL WINS
	CALL SET_PAN
Mas_Es2	LD A,#7F
	IN A,(#FE)
	BIT 4,A
	JR Z,Mas_Es2
Mas10	JP Arrow2

Mark0	CALL ARRcuRS
	XOR A
Mark2	EX AF,AF'
	CALL QFILES
	JR Z,Mas_Esc
	EX AF,AF'
	CALL MASK2

PRNTmrk	CALL panel
	LD A,(QFILESL)
	LD DE,TXT_L
	LD HL,MARK_L
	LD BC,MARKEDL
	EXX
	LD BC,CAT_L
	LD HL,MRKadrL
	JR Z,Mark2_1
	LD A,(QFILESR)
	LD DE,TXT_R
	LD HL,MARK_R
	LD BC,MARKEDR
	EXX
	LD BC,CAT_R
	LD HL,MRKadrR
Mark2_1	LD (Mark2_5+2),HL
	EXX
	LD (Mark2_3+1),HL
	LD (Mark2_4+1),HL
	LD (Mark2_6+1),HL
	LD (HL),0
	INC HL
	LD (HL),0
	EX DE,HL
	LD DE,11
Mark2_2	EX AF,AF'
	ADD HL,DE
	LD A,(HL)
	AND A
	RLA
	JR NC,MarkNxt
	AND A
	RRA
	LD (BC),A
	INC BC
	EXX
	LD HL,16
	CALL mul_hla
	ADD HL,BC
	LD DE,13
	ADD HL,DE
	LD E,(HL)
Mark2_3	LD HL,(#2A2A)
	ADD HL,DE
Mark2_4	LD (#2222),HL
	EXX
MarkNxt	INC HL
	EX AF,AF'
	DEC A
	JR NZ,Mark2_2
Mark2_5	LD (#ED43),BC
Mark2_6	LD HL,(#2A2A)
Mark_M	LD A,#C9
	LD (NotMrk0),A
	CALL M_print
	XOR A
	LD (NotMrk0),A
MODEprt	NOP
	JP Mas_Esc

rename	CALL ARRcuRS
	CALL panel
	PUSH AF
	LD HL,#0604
	LD DE,#0414
	JR Z,RENAM1
	LD H,6+32
RENAM1	EXX
	LD A,40
	CALL WINDOW
	POP AF
	PUSH AF
	LD DE,#0904
	JR Z,R2
	LD D,9+32
R2	LD HL,REN
	CALL PRINT
	INC E
	POP AF
	RET

२. 䠩
RENAME	CALL QFILES
	JP Z,ARROW
	CALL rename
	PUSH AF
	INC HL
	CALL PRINT
	LD HL,(FILEadr)
	LD DE,LINE
	PUSH DE
	LD BC,8
	LDIR
	LD BC,#0820
RENAM22	DEC DE
	LD A,(DE)
	CP C
	JR NZ,RENAM21
	DJNZ RENAM22
RENAM21	INC DE
	LD A,"."
	LD (DE),A
	INC HL
	LD A,(HL)
	INC DE
	LD (DE),A
	INC DE
	LD HL,LINE+10
	AND A
	SBC HL,DE
	JR Z,RENAM23
	LD A,C ; C=" "
RENAM24	LD (DE),A
	INC DE
	DEC L
	JR NZ,RENAM24
RENAM23	POP HL
	POP AF
	LD DE,#0B06
	JR Z,RENAM3
	LD D,11+32
RENAM3	CALL INP_STR
	JP NZ,RENAM10
	CALL compar2
	CALL CONTROm
	LD A,(FILEnum)
	LD HL,16
	CALL mul_hla
	CALL panel
	LD DE,CAT_L
	JR Z,RENAM5
	LD DE,CAT_R
RENAM5	PUSH DE
	ADD HL,DE
	PUSH HL
	LD (RENAM9+1),HL
	LD DE,LINE+8
	LD BC,#2E08
Renam3	LD A,(DE)
	CP B
	JR Z,RENAM4
	DEC DE
	DEC C
	JR NZ,Renam3
	LD A,(DE)
	CP B
	JR Z,RENAM4
	LD BC,8
	JR RENAM6
RENAM4	LD B,0
	INC DE
	LD A,(DE)
	LD DE,8
	ADD HL,DE
	LD (HL),A
RENAM6	POP DE
	LD A,C
	AND A
	JR Z,RENAM7
	LD A,8
	SUB C
	LD HL,LINE
	LDIR
	JR Z,RENAM7
	EX DE,HL
RENAM8	LD (HL)," "
	INC HL
	DEC A
	JR NZ,RENAM8
RENAM7	LD HL,2048+244
	POP DE
	ADD HL,DE
	LD (NDEL2+1),HL
	LD (NotDel+1),DE
	CALL DelFile
	JR NZ,NotDel
	LD HL,(RENAM9+1)
	LD A,(HL)
	CP 1
	JR Z,NotDel
NDEL2	LD HL,0
	DEC (HL)
NotDel	LD HL,0
	LD DE,0
	LD BC,#0906
	CALL DOS
RENAM9	LD HL,0
	LD DE,(FILEadr)
	LD BC,8
	LDIR
	INC DE
	LD A,(HL)
	LD (DE),A
RENAM10	CALL WINS
	CALL SET_PAN
	JP Arrow2

 ப
;DE-. HL-⥪
INP_STR	LD (LINE+12),DE
	LD DE,LINE
	LD A,(DE)
	CP 1
	LD BC,10
	LD A,C
	LDIR
	EX DE,HL
	LD A,32
	LD (HL),A
	INC HL
	LD (HL),C
	JR Z,i_s1
	LD B,11
i_s0	DEC HL
	CP (HL)
	JR NZ,i_s1
	DJNZ i_s0
i_s1	LD A,B
	LD (LINE+14),A
	CALL ESCAPE
INP_ST	LD HL,LINE
	LD DE,(LINE+12)
	CALL PRINT
INP_ST2	LD HL,(LINE+12)
	LD A,(LINE+14)
	ADD A,H
	LD H,A
	CALL scr_adr-1
	LD A,20
	LD (LINE+15),A
KEY	XOR A
	LD (23560),A
KEY2	HALT
	LD A,(LINE+15)
	DEC A
	JR Z,INP_ST2
	LD (LINE+15),A
	CALL escape
	BIT 7,A
	JP NZ,ESCAPE2
	CALL SCANER
	BIT 7,A
	JP NZ,ESCAPE2
	BIT 4,A
	JP NZ,ENTER
	AND 3
	JR NZ,MOVcurs
	LD A,30
	LD (FIRE_Q),A
	LD A,(23560)
	AND A
	JR Z,KEY2
	CP 12
	JR Z,BACKSP
	CP 6
	JR Z,CAPSLK
	CP 32
	JR C,KEY
	CP 128
	JR NC,KEY

	EX AF,AF'
	LD A,(LINE+14)
MODE_IS	CP 10
	JR NC,KEY
	LD HL,LINE
	LD D,0
	LD E,A
	ADD HL,DE
	INC A
	LD (LINE+14),A
	EX AF,AF'
	LD (HL),A
BACK1	JR INP_ST

BACKSP	LD A,(LINE+14)
	AND A
	JR Z,BACK2
	DEC A
	LD (LINE+14),A
BACK2	LD HL,LINE
	LD D,0
	LD E,A
	ADD HL,DE
	LD (HL),32
BACK3	JR BACK1

CAPSLK	LD HL,23658
	LD A,8
	XOR (HL)
	LD (HL),A
CAPSL2	JR KEY

MOVcurs	EX AF,AF'
	LD A,(FIRE_Q)
	DEC A
	JR Z,MOV2
	LD (FIRE_Q),A
	CP 29
	JP NZ,KEY
MOV2	EX AF,AF'
	DEC A
	LD B,A
	LD A,#3C
	XOR B
	LD (MODcurs),A
	LD A,(MODE_IS+1)
	INC A
	LD B,A
	LD A,(LINE+14)
MODcurs	INC A
	CP 255
	JR Z,CAPSL2
	CP B
	JR Z,CAPSL2
	LD (LINE+14),A
	JR BACK3

ESCAPE2	LD A,10
	LD (MODE_IS+1),A
ESCAPE	LD A,(MOUSE)
	AND A
	JR Z,ESC2
ESC1	LD C,#DF
	CALL r_key
	AND 144
	JR NZ,ESC1
ESC2	CALL SCANER
	AND 144
	JR NZ,ESC2
	INC A
	RET
ENTER	CALL ESCAPE2
	XOR A
	RET

MSPEED2	LD A,(M_SP)
	LD B,A
	LD A,30
	SUB B
	LD (SPEED1+1),A
	LD A,27
	SUB B
	LD (S2+1),A
	LD A,22
	SUB B
	LD (S3+1),A
	RET

SPEED0	LD B,0
	NEG
SPEED1	CP 18
	JR NC,SP0
S2	CP 12
	JR NC,SP1
S3	CP 6
	JR NC,SP2
	CP 2
	JR C,Mcount
	DEC A
	RET
Mcount	LD A,0
	INC A
	LD (Mcount+1),A
	CP 3
	JR NC,SPP
	XOR A
	RET
SPP	XOR A
	LD (Mcount+1),A
	INC A
	RET
SP0	ADD A,A
SP1	ADD A,A
SP2	ADD A,A
	RET

ARRcuRS	CALL ch_panM
	JP ARRcurS

CONTROm	CALL panel
CONT1	LD A,(LEFT_D+1)
	JR Z,CONT0
	LD A,(RIGHT_D+1)
CONT0	SUB 65
	LD (23833),A
CONTROc	CALL panel
	LD HL,CAT_L
	JR Z,DEL2_0
	LD HL,CAT_R
DEL2_0	LD DE,BUFD
	LD BC,2304
	LDIR
	INC A
	LD (RESTcat+1),A
	RET

panel	LD A,(PANEL)
	AND A
	RET 